Vault 公式引用指南

此引用指南包括可在 Vault 中使用的运算符和函数的列表。请注意，并非所有函数和运算符都适用于使用公式的 Vault 的所有区域。

数学运算符

+ (加)

描述

计算两个值的总和

使用

value1 + value2

数据类型

• 数字
• 带数字的日期时间（将数字解释为天数）
• 带数字的日期（将数字解释为天数）
• 带时间的日期
• 带间隔的日期
• 带间隔的日期时间

示例

times_in_review__c + 1

将“处于审查中状态的时间”字段递增 1

created_date__v + 30

将创建日期增加 30 天

Date(Year(Today()), Month(Today()), Day(Today())) + Time(12,0,0)

返回代表今天中午的日期时间

Today() + Months(1)

返回下个月同一天

可用性

查看每个类别中包含的内容。

– (减)

描述

计算两个值的差值

使用

value1 - value2

数据类型

• 数字
• 日期
• 日期时间
• 带数字的日期时间（将数字解释为天数）
• 带数字的日期（将数字解释为天数）
• 带日期时间的日期（将日期时间转换为日期）
• 带间隔的日期
• 带间隔的日期时间
• 带时间的时间（以分钟为单位返回时间差值）

示例

suggested_retail_price__c - discount__c

计算折扣后的价格

created_date__v - 1

计算创建日期前一天

completion_date__c - created_date__v

以天数、小时数和分钟数为单位计算两个日期时间之间的差值

Today() - Years(1)

从上一年返回今天的日期

可用性

查看每个类别中包含的内容。

* (乘以)

描述

将两个值相乘

使用

value1 * value2

数据类型

• 数字

示例

monthly_cost__c * 12

返回年成本

可用性

查看每个类别中包含的内容。

/ (除以)

描述

将一个值除以另一个值

使用

value1 / value2

数据类型

• 数字

示例

(measurement1__c + measurement2__c) / 2

返回两次测量结果的平均值

可用性

查看每个类别中包含的内容。

% (余数)

描述

一个值除以另一个值的余数

使用

value1 % value2

数据类型

• 数字

示例

"Weeks:" & Text(Floor(days_required__c / 5)) & "Days:" & Text(days_required__c % 5)

返回包含所需周数和天数的文本字符串

可用性

查看每个类别中包含的内容。

() (括号)

描述

指定先计算左括号和右括号内的表达式

使用

(expression1) expression2

示例

(measurement1__c + measurement2__c) / 2

返回两次测量结果的平均值

可用性

查看每个类别中包含的内容。

逻辑运算符

= (等于)

描述

评估两个值是否相等

使用

value1 = value2

数据类型

• 数字
• 文本
• 日期
• 日期时间
• 带日期时间的日期（将日期时间转换为日期）
• 是/否
• 选项列表（两个选项列表都必须是单值）
• 包含文本的选项列表

示例

Document.annotation_unresolved__v = 0

如果有未解决注释，则返回 true

created_date__v = last_modified_date__v

如果对象记录自创建以来未被修改，则返回 ture（日期时间相等）

name__v = "text"

如果名称值与“文本”匹配，则返回 ture（文本字符串相等）

picklist__c = "text__c"

如果选项列表包含与“text__c”匹配的项，则返回 ture（选项列表值与文本字符串匹配）

可用性

查看每个类别中包含的内容。

! = (不等于)

描述

评估两个值是否不相等

使用

value1 ! = value2

数据类型

• 数字
• 文本
• 日期
• 日期时间
• 带日期时间的日期（将日期时间转换为日期）
• 是/否
• 选项列表（两个选项列表都必须是单值）
• 包含文本的选项列表

示例

amount1__c ! = amount2__c

如果数字不相等，则返回 ture

created_date__v ! = last_modified_date__v

如果对象记录自创建以来已修改，则返回 ture（日期时间不相等）

name__v ! = "text"

如果名称值与“文本”不匹配，则返回 ture（文本字符串不相等）

picklist__c ! = "text__c"

如果选项列表不包含与“text__c”匹配的项，则返回 ture（选项列表值与文本字符串不匹配）

可用性

查看每个类别中包含的内容。

< (小于)

描述

评估第一个值是否小于第二个值

使用

value1 < value2

数据类型

• 数字
• 日期
• 日期时间
• 带日期时间的日期（将日期时间转换为日期）

示例

measurement1__c < measurement2__c

如果测量值 1 小于测量值 2，则返回 ture

If(due_date__c < Today(), "Late", "On-Time")

如果到期日期在当前日期之前，则返回“Late”

(submission_date__c + 15) < approval_date__c

如果批准日期在送审日期之后至少十五天，则返回 ture

可用性

查看每个类别中包含的内容。

<= (小于或等于)

描述

评估一个值是否小于或等于另一个值

使用

value1 <= value2

数据类型

• 数字
• 日期
• 日期时间
• 带日期时间的日期（将日期时间转换为日期）

示例

measurement1__c <= measurement2__c

如果测量值 1 小于或等于测量值 2，则返回 ture

If(due_date__c <= Today(), "Due", "On-Time")

如果到期日期是当前日期或更早，则返回“Due”

可用性

查看每个类别中包含的内容。

> (大于)

描述

评估第一个值是否大于第二个值

使用

value1 > value2

数据类型

• 数字
• 日期
• 日期时间
• 带日期时间的日期（将日期时间转换为日期）

示例

measurement1__c > measurement2__c

如果测量值 1 大于测量值 2，则返回 ture

If(due_date__c > Today(), "On-Time", "Late")

如果到期日期在当前日期之后，则返回“On-Time”，否则返回“Late”

approval_date__c > (submission_date__c + 15)

如果批准日期在送审日期之后至少十五天，则返回 ture

可用性

查看每个类别中包含的内容。

>= (大于或等于)

描述

评估一个值是否大于或等于另一个值

使用

value1 >= value2

数据类型

• 数字
• 日期
• 日期时间
• 带日期时间的日期（将日期时间转换为日期）

示例

measurement1__c >= measurement2__c

如果测量值 1 大于或等于测量值 2，则返回 ture

If(due_date__c >= Today(), "On-Time", "Due")

如果到期日期是当前日期或更晚，则返回“On-Time”，否则返回“Due”

可用性

查看每个类别中包含的内容。

&& (与)

描述

评估两个值或表达式是否为 true

使用

(expression1) && (expression2)

用户可以使用 And() 取代 &&。

示例

(count__c >= expected_count__c) && (Today() < expiration_date__c)

如果计数大于或等于预期计数并且当前日期早于过期日期，则返回 ture

可用性

查看每个类别中包含的内容。

|| (或)

描述

评估两个值或表达式中是否至少有一个为 ture

使用

(expression1) || (expression2)

示例

(count__c >= expected_count__c) || (Today() < expiration_date__c)

如果计数大于或等于预期计数或者当前日期早于过期日期，则返回 ture，如果两个表达式均为 true，也会返回 ture

可用性

查看每个类别中包含的内容。

文本运算符

& (连接)

描述

连接两个或多个文本字符串

使用

text1 & text2

用户可以使用 Concat() 取代 &。

示例

"Study" & name__v

返回结合了对象记录名称的文本字符串“Study”

可用性

查看每个类别中包含的内容。

日期和日期时间函数

日期

描述

指定年、月和日值时返回日期值

使用

Date(year, month, day)

示例

Date(2018, 3, 14)

返回日期 2018-03-14

Date(year(today), month(today()) + 1, day(today()))

返回当前日期一个月后的日期

Date(Year(Today()), Month(Today()), Day(Today())) + Time(12,0,0)

返回代表今天中午的日期时间

可用性

查看每个类别中包含的内容。

DateValue

描述

返回日期时间值的日期部分。此函数也接受时区的第二个可选参数。返回的日期基于指定的时区。

时区参数可以是选项列表、文本字段或时区的文本文字，例如“America/Los_Angeles”或“Asia/Shanghai”。

使用

DateValue(DateTime) 或 DateValue(DateTime, Timezone)

示例

DateValue(audit_end_date_and_time__c)

返回审计结束的日期，不显示时间

示例

DateValue(audit_end_date_and_time__c, @User.timezone__sys)

返回审计结束的日期，不显示用户时区的时间

可用性

查看每个类别中包含的内容。

Day

描述

返回月中的某一天

使用

Day(date)

示例

Day(audit_end_date__c)

返回审计结束日期当月的一天

可用性

查看每个类别中包含的内容。

Days

描述

返回指定天数作为间隔

使用

Days(number)

示例

audit_start_date__c + Days(10)

返回审计开始日期 10 天后的日期

可用性

查看每个类别中包含的内容。

Hour

描述

返回日期时间中的小时值（0 至 23）

返回小时 (UTC)但如果用于构建日期时间，Vault 会将日期时间转换为活动用户的本地时间。

使用

Hour(dateTime) 或 Hour()

示例

(created_date__v)

返回创建日期中的小时

小时()

返回 Vault 时区中的当前小时

可用性

查看每个类别中包含的内容。

Minute

描述

返回日期时间中的分钟值（0 至 59）

返回分钟 (UTC)但如果用于构建日期时间，则日期时间会转换为活动用户的本地时间。

使用

Minute(DateTime) 或 Minute()

示例

Minute(created_date__v)

返回创建日期中的分钟

分钟()

返回 Vault 时区中的当前分钟

可用性

查看每个类别中包含的内容。

Month

描述

返回日期或日期时间所在的月份（数字 1-12）

使用

Month(date), Month(DateTime)

示例

Month(created_date__v)

返回创建日期所在的月份

可用性

查看每个类别中包含的内容。

Months

描述

返回指定月数作为间隔

使用

Months(number)

示例

audit_start_date__c + Months(1)

返回审计开始日期 1 个月后的日期

可用性

查看每个类别中包含的内容。

NetWorkdays

描述

返回两 (2) 个日期/日期时间之间的工作日天数。此功能还接受周末和假期计划的可选参数。管理员可以在业务管理员 > 假期计划或下载并部署带有预先配置假期的 VPK。

使用

NetWorkdays(start_date/datetime, end_date/datetime, weekend_number, holiday_schedule)

示例

NetWorkdays(created_date__v, approval_date__c, 1, “United States”)

返回删除了美国假日的两个日期之间的工作日数

可用性

查看每个类别中包含的内容。

Now

描述

返回当前日期和时间

返回活跃用户的日期时间

使用

Now()

示例

Now() - created_date__v

返回自创建日期以来的天数

可用性

查看每个类别中包含的内容。

Second

描述

返回日期时间中的秒钟值 (0-59)

返回秒钟 (UTC)但如果用于构建日期时间，则日期时间会转换为活动用户的本地时间。

使用

Second(date), Second()

示例

Second(created_date__v)

返回创建日期中的秒钟值

Second()

返回 Vault 时区中的当前秒钟

可用性

查看每个类别中包含的内容。

StartOfDay

描述

返回日期时间，即给定时区中给定日子的开始日期时间

时区参数可以是选项列表、文本字段或时区的文本文字，例如“America/Los_Angeles”或“Asia/Shanghai”。

使用

StartOfDay(date, timezone)

示例

StartOfDay(assigned_date__v, "Europe/Oslo")

如果 assigned_date__v = 2020 年 7 月 1 日，则返回与 2019/07/01 00:00 （奥斯陆时间）对应的 UTC 日期时间。

可用性

查看每个类别中包含的内容。

Time

描述

根据输入的小时、分钟和秒钟值返回时间

使用

Time(hour, minute, second)

示例

Time(12,0,0)

返回代表中午的时间

Time(Hour(Now()), Minute(Now()), Second(Now())) - Time (12,30,0)

以分钟为单位计算两个时间的差值

Date(Year(Today()), Month(Today()), Day(Today())) + Time (12,0,0)

返回代表今天中午的日期时间

可用性

查看每个类别中包含的内容。

Today

描述

返回 Vault 的基础时区中的当前日期；包含变量，可以返回指定时区中的当前日期

时区参数可以是选项列表、文本字段或时区的文本文字，例如“America/Los_Angeles”或“Asia/Shanghai”。

使用

Today(), Today(timezone)

示例

Today() = due_date__c

如果到期日期等于 Vault 的基础时区中的当前日期，则返回 ture

Today("Europe/Oslo") = due_date__c

如果到期日期等于奥斯陆时区中的当前日期，则返回 ture

可用性

查看每个类别中包含的内容。

Today (User)

描述

返回活跃用户的指定时区中的当前日期

在生命周期或工作流中使用时，“用户”是指发起该操作的用户。例如，工作流所有者是指在工作流开始步骤之后立即完成一项操作的“用户”，而在工作流任务步骤之后立即完成一项操作的“用户”则是指完成任务的最后一个用户。

使用

Today("user")

示例

Today("user") = due_date__c

如果到期日期等于活跃用户的时区中的当前日期，则返回 ture

可用性

查看每个类别中包含的内容。

Weekday

描述

返回日期或日期时间所属的周几（数字 1-7）

使用

Weekday(date), Weekday(datetime)

示例

If((Weekday(due_date__v) = 1) || (Weekday(due_date__v) = 7)), "Weekend Due Date", "Not a weekend due date")

如果到期日期是星期日或星期六，则返回“Weekend Due Date”，否则返回“Not a weekend due date”

可用性

查看每个类别中包含的内容。

工作日

描述

返回未来 N 天的日期，不考虑周末和假期（可选）。此功能还接受周末和假期计划的可选参数。管理员可以在业务管理员 > 假期计划或下载并部署带有预先配置假期的 VPK。

使用

Workday(start_date/datetime, number_of_days, weekend_number, holiday_schedule)

示例

Workday(created_date__v, N)

返回比创建日期早 N 天的日期，不包括周六和周日

Workday(created_date__v, N, 1, “United States”)

返回比创建日期早 N 天的日期，不包括美国假日

可用性

查看每个类别中包含的内容。

Year

描述

返回日期中的年

使用

Year(date) 或 Year(DateTime)

示例

Date(Year(Today()) + 1, Month(Today()), Day(Today()))

返回下一年的当前日期的同一天

可用性

查看每个类别中包含的内容。

Years

描述

返回指定年数作为间隔

使用

Years(number)

示例

Today() + Years(1)

返回下一年的当前日期的同一天

可用性

查看每个类别中包含的内容。

弃用函数

以下函数已弃用。

• DateAdd：使用+ 运算符。
• DateTimeAdd：使用 + 运算符。
• DateDiff：使用 – 运算符。
• DateTimeDiff：使用 – 运算符。

数学函数

Abs

描述

计算数字的绝对值

使用

Abs(number)

示例

Abs(height_1__c - height_2__c)

返回高度值 1 和高度值 2 之间的差值（正数值），无论哪个测量值更大

可用性

查看每个类别中包含的内容。

Average

描述

计算一组数字的平均值

使用

Average(number1, number2, ...)

示例

Average(1.5, 2, 3, 4, 5.0)

返回 3.1

可用性

查看每个类别中包含的内容。

Ceiling

描述

返回下一个大于该值的整数

使用

Ceiling(number)

示例

Ceiling(14.2)

通过向上舍入到最接近的整数返回 15

Ceiling(-14.2)

通过向上舍入到最接近的整数返回 -14

可用性

查看每个类别中包含的内容。

Floor

描述

返回下一个小于该值的整数

使用

Floor(number)

示例

Floor(14.2)

通过向下舍入到最接近的整数返回 14

Floor(-14.2)

通过向下舍入到最接近的整数返回 -15

可用性

查看每个类别中包含的内容。

Max

描述

返回该组中的最大值

使用

Max(value1, value2, …)

数据类型

• 数字
• 日期
• 日期时间

您不能在单个 Max() 请求中混合数据类型。如果您需要混合日期和日期时间，我们建议使用 DateValue 将日期时间转换为日期。

示例

Max(measurement1__c, measurement2__c, measurement3__c)

返回最大的测量值数字

Max((units__c * price__c), min_value__c)

返回单位乘以价格的乘积与最小值之中的较大值

Max(approval_date__c, today(), completed_date__v)

返回给定日期中的较大值，即最近（最新）的日期

可用性

查看每个类别中包含的内容。

Min

描述

返回该组中的最低值

使用

Min(value1, value2, …)

数据类型

• 数字
• 日期
• 日期时间

您不能在单个 Min() 请求中混合数据类型。如果您需要混合日期和日期时间，我们建议使用 DateValue 将日期时间转换为日期。

示例

Min((units__c * price__c), max_value__c)

返回单位乘以价格的乘积与最大值之中的较小值

Min(approval_date__c, today(), completed_date__v

返回给定日期中的较小值，即最早（最旧）的日期

可用性

查看每个类别中包含的内容。

Power

描述

给定两个数字，按照第二个数字中指定的次数将第一个数字乘以其本身

使用

Power(number, number)

示例

Power(5, 3)

5 乘以其自身 3 次返回 125：5 * 5 * 5

Power(8, 1/3)

8 乘以其自身 1/3 次返回 2：8 * ⅓

Power(9, 0)

返回 1；如果第二个引数为零，则结果始终为 1

可用性

查看每个类别中包含的内容。

Round

描述

将数字四舍五入为定义的小数位数

使用

Round(number, number)

示例

Round(5.5, 0)

返回“6”，5.5 向上舍入，不含小数值

Round(5.54, 1)

返回“5.5”，5.54 向下舍入，含一个小数位

Round(-5.5, 0)

返回“-6”，-5.5 四舍五入到最接近的数字，不含小数值

可用性

查看每个类别中包含的内容。

Round(重要)

描述

将数字四舍五入为定义的有效数字

使用

Round(number, number_of_digits, "significant") 或 Round(number, number_of_digits, "significant-astm")

示例

Round(0.445, 2, "significant")

返回“0.45”

Round(0.445, 2, “significant-astm”)

返回“0.44”

可用性

查看每个类别中包含的内容。

Sqrt

描述

返回数字的平方根

使用

Sqrt(number)

示例

Sqrt(25)

返回“5”，即 25 的平方根

可用性

查看每个类别中包含的内容。

Sum

描述

将给定的数字相加

使用

Sum(number1, number2, ...)

示例

Sum(1.5, 2, 3, 4, 5.0)

返回 15.5

可用性

查看每个类别中包含的内容。

Value

描述

以数字形式返回文本字符串；如果文本不能解析为数字，该函数将导致错误

使用

Value(text)

示例

Value(Right("S1234",4)

返回数字“1234”

可用性

查看每个类别中包含的内容。

弃用函数

• NumberEquals：使用 = 运算符。

逻辑函数

And

描述

在所有表达式为 true 时返回 ture

用户可以使用 && 取代 And()。

使用

And(expression1, expression2, …)

示例

And(due_date__v = today(), status__v ! = "已完成")

如果对象记录的到期日期是今天并且其状态为“未完成”，则返回 ture

可用性

查看每个类别中包含的内容。

Case

描述

将表达式的值与每个 case 值进行比较，并返回配对结果；如果没有值匹配，则返回最后一个引数

表达式引数接受以下数据类型：数字、文本、是/否、选项列表。使用选项列表字段时，该字段返回值名称 (study123__c) 而不是值标签 (Study123)。

使用

Case(expression1, value1, result1, value2, result2, else_result)

示例

Case(WeekDay(Today()), 1, "Sunday", 2, "Monday", 3, "Tuesday", 4, "Wednesday", 5, "Thursday", 6, "Friday", 7, "Saturday", "None")

返回当天的名称

Case(picklist__c, "sunday__c", 1, "monday__c", 2, "tuesday__c", 3, "wednesday__c", 4, "thursday__c", 5, "friday__c", 6, "saturday__c", 7, 0)

返回使用选项列表值名称 (sunday__c) 而不是其标签 (Sunday) 在选项列表中选择的天数

可用性

查看每个类别中包含的内容。

If

描述

确定表达式是 true 还是 false；如果为 true 则返回给定值，如果为 false 则返回另一个值

使用

If(expression, value_if_true, value_if_false)

示例

If(Or(IsBlank(measurement1__v), IsBlank(completed_date__v)), "Incomplete", "Complete")

如果测量值 1 和完成日期均未留空，则返回“Complete”

可用性

查看每个类别中包含的内容。

Includes

描述

当多值选项列表包含与定义的字符串或单值选项列表匹配的名称时返回 ture

使用

Includes(multi-value picklist, string) 或 Includes(multi-value picklist, single-value picklist)

示例

Includes(colors__c, 'red__c')

如果“Red”是多值选项列表“colors__c”中选择的值之一，则返回 ture

Includes(colors__c, Picklist.field__v.value__v)：如果当前在多值选项列表“colors__c”中选择了单值选项列表中定义的值，则返回 ture

可用性

IsBlank

描述

值为空时返回 ture

使用

IsBlank(expression)

示例

If(Or(IsBlank(measurement1__v), IsBlank(completed_date__v)), "Incomplete", "Complete")

如果测量值 1 和完成日期均未留空，则返回“Complete”

可用性

查看每个类别中包含的内容。

IsNumber

描述

在值为数字时返回 ture

使用

IsNumber(text)

示例

If(IsNumber(measurement1__c),measurement1__c/100,0)

如果测量值 1 是数字，则返回测量值 1 除以 100 的值；否则，返回“0”

可用性

查看每个类别中包含的内容。

Not

描述

在表达式为 false 时，返回 ture；在表达式为 ture 时，返回 false

使用

Not(expression)

示例

Not(isBlank(due_date__c))

如果填充了“到期日期”字段，则返回 true

可用性

查看每个类别中包含的内容。

Or

描述

评估两个值或表达式中是否至少有一个为 ture

使用

(expression1) || (expression2)

示例

Or((count__c >= expected_count__c),(Today() < expiration_date__c))

如果计数大于或等于预期计数或者当前日期早于过期日期，则返回 ture，如果两个表达式均为 true，也会返回 ture

Or(due_date__v = Today(), due_date__v = Today() + 1)

如果对象记录的到期日期是今天或明天，则返回 ture

可用性

查看每个类别中包含的内容。

文本函数

Concat

描述

连接两个或多个文本字符串

使用

Concat(text1, text2, …)

用户可以使用 & 取代 Concat()。

示例

Concat("Study", name__v)

返回结合了对象记录名称的文本字符串“Study”，例如“Study123”

可用性

查看每个类别中包含的内容。

Find

描述

返回字符串在文本字符串中的位置

使用

查找（潜台词文本、文本）

示例

Find(" ", "4280 Hacienda Dr, Pleasanton, CA")

返回 5，地址中第一个空格的位置

可用性

查看每个类别中包含的内容。

ID

描述

将记录 ID 作为对象引用值的文本返回

使用

ID （文本/对象_记录）

示例

ID（国家__c）

将国家__c 字段中引用的对象记录 ID 返回

可用性

查看每个类别中包含的内容。

Icon

描述

根据公式评估显示图标

使用

icon(name, color, text)

文本引数是可选的，向用户提供替代文本。请参阅 Vault 支持的图标，了解更多信息。

示例

If(completeness_v = 'complete_v', Icon("circle", "#00C345", "Complete"), Icon("circle", "#ff0000", "Incomplete"))：根据完整性选项列表值显示状态

可用性

查看每个类别中包含的内容。

Left

描述

返回文本字符串开头中的指定字符数

使用

Left(text, position)

示例

Left(name__v, 5) & " - " & abbreviation__c

返回名称的前五个字符及其缩写，例如“Chole – CC”

可用性

查看每个类别中包含的内容。

Length

描述

返回指定文本字符串中的字符数

使用

Length(text)

示例

Length(name__v)

返回“名称”字段中的字符数

可用性

查看每个类别中包含的内容。

Lower

描述

将指定文本字符串中的所有字母转换为小写字母

使用

Lower(text)

示例

Lower("Company A")

返回文本字符串“company a”

可用性

查看每个类别中包含的内容。

Middle

描述

返回两个指定位置之间的文本字符数

使用

Middle(text, start_position, end_position)

示例

Middle("4280 Hacienda Dr, Pleasanton, CA", 6, 13)

返回文本字符串“Hacienda”

可用性

查看每个类别中包含的内容。

Right

描述

从文本字符串的末尾返回指定数量的字符

使用

Right(text, number)

示例

Value(Right("S1234",4))

返回数字“1234”

可用性

查看每个类别中包含的内容。

Substitute

描述

用新文本替换文本字符串中的旧文本

使用

Substitute(text, old_text, new_text)

示例

Substitute("Total cost of ownership: $1,000", "$", "￡")

将字符串中的美元符号转换为英镑符号

可用性

查看每个类别中包含的内容。

文本

描述

根据指定格式将值转换为文本

请参阅日期格式和数字格式，了解更多信息。

使用

文本（日期/时间/数字，格式）)或 文本（周期_状态/参数选用表_数值/对象_记录）

将数字转换为文本时，格式引数是可选的。您必须用双引号（“”）括起指定格式。如果您传递没有指定格式的 Text() 函数，Vault 将保留当前定义的小数位数。对于具有不同小数位数的操作数，Vault 会保留最大的小数位数。例如，Text(3.14+2.345) 返回 5.485。

示例

"Today is" & Text(Today(), "dddd")

返回文本字符串“Today is”，后跟周几的全称，例如，“Today is Monday”

Text(state__v)

返回文本字符串“Planned”，即生命周期状态标签

Text(Document.major_version_number__v, "###") & "."& 文本（文件.次要_版本_编号__v，“###”）

返回文本字符串“#.#”，其中 # 表示文档的主要和次要版本号，例如“12.2”

文本（区域__c）

将区域__c 字段中引用的对象记录 名称返回

可用性

查看每个类别中包含的内容。

Trim

描述

将空格和制表符从文本字符串开头和结尾中移除

使用

Trim(text)

示例

Trim(" Phase III ")

通过删除字符串开头的空格，返回文本字符串“Phase III”

可用性

查看每个类别中包含的内容。

Upper

描述

将指定文本字符串中的所有字母转换为大写字母

使用

Upper(text)

示例

Upper("Company A")

返回文本字符串“COMPANY A”

可用性

查看每个类别中包含的内容。

其他函数

Hyperlink

描述

将文本显示为可点击链接

使用

Hyperlink(href, label, target, connection)

您必须将此函数与使用链接返回类型的公式字段一起使用。

引数

• href：该链接的可点击 URL；您可以使用文本字符串、其他函数、字段引用和返回字符串的表达式。使用文字文本字符串时，必须将它们括在单引号 (”) 中。
• label：在 UI 中显示为链接的文本；您可以使用文本字符串、其他函数、字段引用和在此引数中返回字符串的表达式。使用文字文本字符串时，必须将它们括在单引号 (”) 中。
• target：确定该链接是在当前标签页中打开还是在新的浏览器标签页/窗口中打开；接受“new_window”和“same_window”。您必须用单引号 (”) 将属性括起来。
• Connection：（可选）利用配置的连接对象记录在 URL 中填充另一个 Vault 的 DNS；格式为 @Connection.{connection API name}，例如 @Connection.veepharm_v2v。请参阅创建和管理连接，了解更多信息。

示例

Hyperlink('https://veepharm.com', 'VeePharm Site', 'new_window')

此示例可简单导航至特定 URL。该字段将显示“VeePharm 机构”并导航到提供的 URL。该站点将在新的标签页或窗口中打开，而不是在同一个标签页或窗口中打开。

Hyperlink(Concat("https://veepharm.theorgwiki.com/employees/", first_name__sys, "_", last_name__sys), Concat(first_name__sys, " ", last_name__sys), 'new_window')

此示例可以与用户对象记录一起使用，以返回到 OrgWiki 上用户的公司资料。该公式显示标有用户名字和姓氏的可点击链接，并导航到用户的 OrgWiki 个人资料页面。

Hyperlink(Concat("/ui/#t/0TB00000000N04/", related_record_id__c), related_record_label__c, 'same_window', @Connection.veepharm_v2v)

此示例将 Vault 到 Vault 连接记录用于 API 名称“veepharm_v2v”。href 引数与 connection 引数一起使用时，可将用户导航到已连接 Vault 中的特定记录。由于此示例使用连接记录，它只包含 href 引数中 DNS 之后的 URL 部分。

可用性

此功能仅适用于返回类型为链接的对象上的公式类型字段。

查看每个类别中包含的内容。

RecordByLabel

描述

返回指定对象标签的对象引用（如有多个，则为最早日期）

使用

RecordByLabel()

示例

RecordByLabel (“Cholecap”)

返回 Cholecap 产品的对象引用。

可用性

查看每个类别中包含的内容。

State

描述

返回对象或文档生命周期状态的名称

使用

state__v

示例

state__v = "planned_state__v"

如果生命周期状态名称值为 planned_state__v，则返回 ture

可用性

查看每个类别中包含的内容。

Urlencode

描述

将文本字符串中的字符转换为可通过 URL 传输的格式，例如，将空格更改为 %20

使用

Urlencode(text)

示例

Hyperlink(Concat("https://www.google.com/search?q=", Urlencode(claim_text__c)), 'Search', 'new_window')

此示例对声明文本字段中的文本执行 Google 搜索。此字段可能包含空格及其他非 URL 编码字符。该公式使用 Urlencode() 对字符串进行正确编码。

可用性

查看每个类别中包含的内容。

日期格式

数字格式

函数和运算符可用性

Vault 中的各种管理区域允许使用不同的函数和运算符。您可以在上面的“可用性”节段中查看给定函数或运算符的可用位置。

• 对象配置包括对象字段的默认设置、对象的公式类型字段、对象页面布局规则、工作流启动步骤规则和记录验证规则。
• 对象生命周期操作包括更新记录字段工作流操作和更新记录字段生命周期状态入口操作。
• 文档生命周期操作包括通过公式设置字段生命周期状态入口操作和更新文档字段工作流操作。

系统变量

系统变量是存储 Vault 可以引用的值的动态对象。这些变量是动态的，因为它们的值会根据您的使用上下文而变化。例如，@User 指向活跃用户的个人资料，并允许访问电子邮件地址等字段值。

选项列表值表达式

您可以使用表达式来引用公式中的选项列表值。

使用

选项列表。<选项列表名称>。<选项列表值名称>

示例

Picklist.impact__c.high__c

在“影响”选项列表中返回“上限”值。

if(object_type__v = "Action Plan", Picklist.ap_securityc.analysis_and_action_planc, Picklist.ap_securityc.action_plan__c)

如果对象类型是“行动计划”，则从“行动计划安全”选项列表中返回“分析和行动计划”值；否则，从“行动计划安全”选项列表中返回“行动计划”值。

备注和格式设置

备注和格式可以帮助您和其他管理员了解公式表达式的工作原理。

您可以按照以下规则在公式表达式字段中添加备注：

• 备注必须是字段中的第一个文本
• 备注应遵循此格式：/* {COMMENT} */

Vault 在公式表达式中保留特定的格式设置：

• 换行
• 空格

Null 值

您可以使用公式表达式返回 NULL 值，这会将字段值设置为空。

每当 Vault 在计算公式表达式时因为 NULL 值而遇到错误时，Vault 都会返回 NULL 值。例如，NULL + 1 将返回 NULL。